Kosmische Rotverschiebung

Deutschsprachige Version
Benutzeravatar
Yukterez
Administrator
Beiträge: 272
Registriert: Mi 21. Okt 2015, 02:16

Kosmische Rotverschiebung

Beitragvon Yukterez » Mi 11. Nov 2015, 02:18

Wenn wir auf kosmologischen Skalen ein rotverschobenes Objekt sehen können wir daraus unter anderem ablesen

1) wie viele Jahre lang sein Licht bis zu uns gereist ist
2) wie viele Lichtjahre es von uns entfernt war als es sein Licht aussandte
3) wie weit es bis jetzt wo wir das Licht empfangen gekommen ist
4) wie schnell das Objekt sich damals von uns entfernt hat
5) wie schnell es sich heute von uns entfernt

Code: Alles auswählen

(* Syntax: Mathematica ||| lcdm.yukterez.net *)

kg = 1; m = 1; sek = 1;  K = 1; (* Units *)

set = {"GlobalAdaptive", "MaxErrorIncreases" -> 100, Method -> "GaussKronrodRule"}; (* Integration Rule *)
n   = 100; (* Recursion Depth *)
tE  = 300 Gyr;  (* Eventhorizon Limit *)

c       = 299792458 m/sek; (* Lightspeed *)
ca      = 1; (* Perturbation Velocity *)
G       = 667384*^-16 m^3 kg^-1 sek^-2;  (* Newton Constant *)
Gyr     = 10^7*36525*24*3600*sek; (* Billion Year Scale *)
Glyr    = Gyr*c; (* Billion Lightyear Scale *)
Mpc     = 30856775777948584200000 m; (* Megaparsec *)
kB      = 13806488*^-30 kg m^2/sek^2/K; (* Boltzmann *)
h       = 662606957*^-42 kg m^2/sek; (* Planck *)
ρr      = 8 π^5 kB^4 T^4/15/c^5/h^3; (* Radiation Density *)
ρR      = 1.68132 ρr; (* Radiation + Neutrinos *)
ρΛ      = ρc[H0] ΩΛ; (* Dark Energy Density *)
T       = 2725/1000 K; (* CMB Temperature *)

ρc[H_] := 3 H^2/8/π/G; (* Critical Density *)

H0 = 67150 m/Mpc/sek; (* Hubble Constant *)
ΩR = ρR/ρc[H0]; ΩM = 317/1000; ΩΛ = 683/1000 - ΩR; ΩT = ΩR + ΩM + ΩΛ; ΩK = 1 - ΩT; (* Density Parameters *)

aE[t_]      := Power[(Sqrt[ΩM/ΩΛ] Sinh[(3 H0 Sqrt[ΩΛ])/2 t])^2, (3)^-1]; (* Solving Region *)
w[a_, w0_] := (1 + w0) (Sqrt[1 + (ΩΛ^-1 - 1) a^-3] - (ΩΛ^-1 -1) a^-3 Tanh[1/Sqrt[1 + (ΩΛ^-1 - 1) a^-3]]^-1)^2 (1/Sqrt[ΩΛ] - (ΩΛ^-1 - 1) Tanh[Sqrt[ΩΛ]]^-1)^-2 -1;

F[a_, w0_] := Sqrt[ΩR a^-4 + ΩM a^-3 + ΩK a^-2 + ΩΛ a^(-3 (w[a, w0] + 1))]; (* Density Function by Scalefactor*)
φ[z_, w0_] := Sqrt[ΩR (z + 1)^4 + ΩM (z + 1)^3 + ΩK (z + 1)^2 + ΩΛ ((1 + z)^(3 (w[1/(z + 1), w0] + 1))) ]; (* Density Function by Redshift *)
H[a_, w0_] := H0 F[a, w0]; (* Hubble Parameter by Scalefactor *)
ε[z_, w0_] := H0 φ[z, w0]; (* Hubble Parameter by Redshift *)

int[f_, {x_, xmin_, xmax_}] := Quiet[NIntegrate[f, {x, xmin, xmax}, Method -> set, MaxRecursion -> n]];

ta[A_, w0_] := int[1/a/ H[a, w0], {a, 0, A}]; (* Time by Scalefactor *)
α[τ_, w0_]  := Quiet[A /.FindRoot[ta[A, w0] - τ, {A, 1}]] (* Scalefactor by Time *)

tz[Z_, w0_] := int[1/(1 + z)/ ε[z, w0], {z, Z, \[Infinity]}]; (* Time by Redshift *)
χ[τ_, w0_]  := Z /. Quiet[FindRoot[tz[Z, w0] - τ, {Z, 0}]] (* Redshift by Time *)

rH[τ_, w0_] := c/H[α[τ, w0], w0]; (* Hubble Radius *)

lC[τ_, w0_]     := int[-c α[τ, w0]/a^2/H[a, w0], {a, 1, α[τ, w0]}]; (* Light Cone of t0 *)
Lc[τ_, t_, w0_] := int[-c α[τ, w0]/a^2/H[a, w0], {a, α[t, w0], α[τ, w0]}]; (* Light Cone of t *)
eH[τ_, w0_]     := α[τ, w0] int[c/(α[time, w0]), {time, τ, tE}]; (* Event Horizon *)
pH[τ_, w0_]     := int[-α[τ, w0] c/a^2/H[a, w0], {a, α[τ, w0], 0}]; (* Particle Horizon *)
g[τ_, w0_]      := tc /. Quiet[FindRoot[pH[tc, w0]/c - τ, {tc, τ}]]; (* Conformal Time *)

ωR[τ_, w0_] := ΩR α[τ, w0]^-4/ρc[H[α[τ, w0]]]; (* Radiation Evolution *)
ωM[τ_, w0_] := ΩM α[τ, w0]^-3/ρc[H[α[τ, w0]]]; (* Matter Evolution *)
ωK[τ_, w0_] := ΩK α[τ, w0]^-2/ρc[H[α[τ, w0]]]; (* Curvature Evolution *)
ωΛ[τ_, w0_] := ΩΛ α[τ, w0]^(-3 (w[α[τ, w0], w0] + 1))/ρc[H[α[τ, w]]]; (* Dark Energy Evolution *)

t0[w0_] := ta[1, w0]/Gyr; (* Age of the Universe, now *)
"t0 in Gyr" -> t0[-1]

Plot[(tz[0, -1] - tz[z2, -1])/Gyr, {z2, 0, 20}, Frame -> True,
 PlotRange -> All, PlotStyle -> {Red, Thick}]
(* Light Travel Time *)

Plot[lC[tz[z2, -1], -1]/Glyr, {z2, 0, 20}, Frame -> True,
 PlotRange -> All, PlotStyle -> {Green, Thick}]
(* Distance at Emission *)

Plot[lC[tz[z2, -1], -1] (z2 + 1)/Glyr, {z2, 0, 20}, Frame -> True,
 PlotRange -> All, PlotStyle -> {Blue, Thick}]
(* Distance at Absorption *)

Plot[ε[z2, -1] lC[tz[z2, -1], -1]/c, {z2, 0, 20}, Frame -> True,
 PlotRange -> All, PlotStyle -> {Orange, Thick}]
(* Recessional Velocity at Emission *)

Plot[H0 lC[tz[z2, -1], -1] (z2 + 1)/c, {z2, 0, 20}, Frame -> True,
 PlotRange -> All, PlotStyle -> {Brown, Thick}]
(* Recessional Velocity at Absorption *)

v = (2 c z + c z^2)/(2 + 2 z + z^2)/c; Plot[v, {z, 0, 20}, Frame -> True,
 PlotRange -> All, PlotStyle -> {Magenta, Thick}]
(* Local Minkowski Redshift *)

z1  = 20; (* Redshift *)
t1  = tz[z1, -1]; "Age at Emission" -> t1/Gyr "Gyr"
tr  = tz[0, -1] - tz[z1, -1]; "Light Travel Time" -> tr/Gyr "Gyr"
lC1 = lC[t1, -1]; "Distance at Emission" -> lC1/Glyr "Glyr"
lC2 = lC[t1, -1] (z1 + 1); "Distance at Absorption" -> lC2/Glyr "Glyr"
v1  = ε[z1, -1] lC1; "Recessional Velocity at Emission" -> v1/c "c"
v2  = H0 lC2; "Recessional Velocity at Absorption" -> v2/c "c"

Die verwendeten kosmischen Parameter sind H0 = 67150 m/Mpc/sek; ΩR = 548e-5; ΩM = 317/1000; ΩΛ = 1-ΩR-ΩM; ΩK = 0
Damit ergibt sich ein Weltalter von 13.8196 Gyr. Die Plots gehen bis zu einer Rotverschiebung von z = 20:
________________________________________________________

Plot 1: Lichtreisezeit; x = z, y = t (in Gyr)

Bild

Das um den Faktor (20+1) rotverschobene Licht war 13.64 Mrd Jahre lang unterwegs.
________________________________________________________

Plot 2: Abstand damals; x = z, y = d (in Glyr)

Bild

Unser Testobjekt war als es sein Licht aussandte 1.7 Mrd Lj von uns entfernt.
________________________________________________________

Plot 3: Abstand heute; x = z, y = d (in Glyr)

Bild

Heute ist es bereits 35 Mrd Lj von uns entfernt (der maximale Partikelhorizont für z→∞ betrüge 46.386 Mrd Lj).
________________________________________________________

Plot 4: Geschwindigkeit damals; x = z, y = v (in c)

Bild

Die Rezessionsgeschwindigkeit des Objekts relativ zu uns betrug damals 6.35 fache Lichtgeschwindigkeit.
________________________________________________________

Plot 5: Geschwindigkeit heute; x = z, y = v (in c)

Bild

Heute beträgt die Rezessionsgeschwindigkeit unseres Objekts 2.46 c relativ zu uns.
________________________________________________________

Plot 6: zum Vergleich die Eigengeschwindigkeit im lokalen Minkowskiraum; x = z, y = v (in c)

Bild

Im lokalen nichtexpandierenden Raum würde die Lichtgeschwindigkeit auch bei z=∞ nicht überschritten.
________________________________________________________

Die Trajektorie unseres Objekts (rot) in physikalischen und mitbewegten Koordinaten:

Bild
________________________________________________________

Das verwendete Modell ist ΛCDM/FLRW mit den Daten von Planck 2013. Wenn eine Kombination aus Eigenbewegung im lokalen Raum und Rezessionsgeschwindigkeit mit dem expandierenden Raum vorliegt werden beide Faktoren (z+1) miteinander multipliziert (die Eigengeschwindigkeit zum Zeitpunkt der Emission ist dann die Ausschlaggebende). Die Abweichung in der Rotverschiebung durch Eigenbewegung ist aber normalerweise vernachläßigbar klein (sie beträgt in etwa ±0.2%).
Bild
by Simon Tyran, Vienna @ minds || gab || wikipedia || stackexchange || License: CC-BY 4. If images don't load: [ctrl]+[F5]Bild

Benutzeravatar
Yukterez
Administrator
Beiträge: 272
Registriert: Mi 21. Okt 2015, 02:16

Rekombinationsfläche

Beitragvon Yukterez » Mi 11. Nov 2015, 02:19

Wikipedia hat geschrieben:Currently, the objects with the highest known redshifts are galaxies and the objects producing gamma ray bursts. The highest confirmed spectroscopic redshift of a galaxy is that of UDFy-38135539 at a redshift of z = 8.6

Die heute bei uns eintreffende Hintergrundstrahlung hat allerdings eine Rotverschiebung von z = 1089.
Zu der Zeit gab es dort zwar noch keine voneinander unterscheidbaren Objekte wie Sterne oder Galaxien sondern nur mehr oder weniger homogene Ursuppe, aber nichtsdestotrotz hier die Zahlen für den wirklich allerhöchsten beobachtbaren Redshift:

Bild
Bild
by Simon Tyran, Vienna @ minds || gab || wikipedia || stackexchange || License: CC-BY 4. If images don't load: [ctrl]+[F5]Bild

Benutzeravatar
Yukterez
Administrator
Beiträge: 272
Registriert: Mi 21. Okt 2015, 02:16

Rezessionsgeschwindigkeit

Beitragvon Yukterez » Mi 11. Nov 2015, 02:23

Wenn man weiter nachrechnet stellt sich heraus dass sich alle Koordinaten mit einer Rotverschiebung von

z > 1.5855 zu dem Zeitpunkt als sie ihr Licht aussandten mit v > c von uns entfernten, und alle mit
z > 1.4855 heute mit einer Rezessionsgeschwindigkeit von v > c vor uns fliehen. Bei
z = 1.8963 ist das Objekt heute wieder genau so schnell wie damals (1.1572 c).

Davis & Lineweaver haben geschrieben:
Since their worldlines have always been beyond the Hubble sphere these objects were, are, and always have been, receding from us faster than the speed of light.

Bild
Achsen: x = Rotverschiebung z, y = Rezessionsgeschwindigkeit (Einheit: c)


Man sieht jetzt auch dass Objekte mit z < 1.8963 heute schneller sind als zum Zeitpunkt wo sie ihr Licht aussandten (die Expansionsrate hat sich seither nicht so stark verändert wie ihr Abstand), während Objekte mit z > 1.8963 inzwischen langsamer geworden sind (die Expansionsrate ist in der längeren Zeit wo das Licht unterwegs war stärker abgefallen als sich der Abstand des Objekts zu uns erhöht hat).

Da die Rezessionsgeschwindigkeit das Produkt aus Expansionsrate und Abstand ist und die Expansionsrate in Zukunft fast konstant bleiben wird beschleunigen die abgebremsten Objekte inzwischen wieder (auch wenn sie ihre ursprüngliche Geschwindigkeit noch nicht wiedererlangt haben), siehe auch den anderen Faden über die beschleunigte Expansion. Am Raum:Zeit-Plot ist der Übergang zur Beschleunigung übrigens dort wo die strichlierte Kurve (Skalenfaktor) anfängt sich nicht mehr nach oben sondern seitauswärts zu krümmen zu sehen (die Schubumkehr war ziemlich genau 8 Mrd Jahre nach dem Urknall, das ist in etwa bei z = 0.6).

Code: Alles auswählen

(* Anhang zum Code in Beitrag 1 *)
Quiet[FindRoot[\[Eta][Z1, -1] lC[tz[Z1, -1], -1] - c, {Z1, 0}]] (* v>c damals *)
Quiet[FindRoot[H0 lC[tz[Z1, -1], -1] (Z1 + 1) - c, {Z1, 0}]] (* v>c heute *)
Quiet[FindRoot[H0 lC[tz[Z1, -1], -1] (Z1 + 1) - \[Eta][Z1, -1] lC[tz[Z1, -1], -1], {Z1, 1}]] (* Gleichstand *)


Cosmological Redshift - Distance - Light Travel Time, Proper & Comoving: Calculations, Simon Tyran, Wien (Vienna)
Bild
by Simon Tyran, Vienna @ minds || gab || wikipedia || stackexchange || License: CC-BY 4. If images don't load: [ctrl]+[F5]Bild

Benutzeravatar
Yukterez
Administrator
Beiträge: 272
Registriert: Mi 21. Okt 2015, 02:16

Beispiel: Entfernung und Geschwindigkeit von UDFy-38135539

Beitragvon Yukterez » Di 15. Mär 2016, 02:28

Objekt: UDFy-38135539 | z = 8.55

Code: Alles auswählen

(* Syntax: Mathematica ||| lcdm.yukterez.net *)

kg = 1; m = 1; sek = 1;  K = 1; (* Units *)

set = {"GlobalAdaptive", "MaxErrorIncreases" -> 100, Method -> "GaussKronrodRule"}; (* Integration Rule *)
n   = 100; (* Recursion Depth *)
tE  = 300 Gyr;  (* Eventhorizon Limit *)

c       = 299792458 m/sek; (* Lightspeed *)
ca      = 1; (* Perturbation Velocity *)
G       = 667384*^-16 m^3 kg^-1 sek^-2;  (* Newton Constant *)
Gyr     = 10^7*36525*24*3600*sek; (* Billion Year Scale *)
Glyr    = Gyr*c; (* Billion Lightyear Scale *)
Mpc     = 30856775777948584200000 m; (* Megaparsec *)
kB      = 13806488*^-30 kg m^2/sek^2/K; (* Boltzmann *)
h       = 662606957*^-42 kg m^2/sek; (* Planck *)
ρr      = 8 π^5 kB^4 T^4/15/c^5/h^3; (* Radiation Density *)
ρR      = 1.68132 ρr; (* Radiation + Neutrinos *)
ρΛ      = ρc[H0] ΩΛ; (* Dark Energy Density *)
T       = 2725/1000 K; (* CMB Temperature *)

ρc[H_] := 3 H^2/8/π/G; (* Critical Density *)

H0 = 67150 m/Mpc/sek; (* Hubble Constant *)
ΩR = ρR/ρc[H0]; ΩM = 317/1000; ΩΛ = 683/1000 - ΩR; ΩT = ΩR + ΩM + ΩΛ; ΩK = 1 - ΩT; (* Density Parameters *)

aE[t_]      := Power[(Sqrt[ΩM/ΩΛ] Sinh[(3 H0 Sqrt[ΩΛ])/2 t])^2, (3)^-1]; (* Solving Region *)
w[a_, w0_] := (1 + w0) (Sqrt[1 + (ΩΛ^-1 - 1) a^-3] - (ΩΛ^-1 -1) a^-3 Tanh[1/Sqrt[1 + (ΩΛ^-1 - 1) a^-3]]^-1)^2 (1/Sqrt[ΩΛ] - (ΩΛ^-1 - 1) Tanh[Sqrt[ΩΛ]]^-1)^-2 -1;

F[a_, w0_] := Sqrt[ΩR a^-4 + ΩM a^-3 + ΩK a^-2 + ΩΛ a^(-3 (w[a, w0] + 1))]; (* Density Function by Scalefactor*)
φ[z_, w0_] := Sqrt[ΩR (z + 1)^4 + ΩM (z + 1)^3 + ΩK (z + 1)^2 + ΩΛ ((1 + z)^(3 (w[1/(z + 1), w0] + 1))) ]; (* Density Function by Redshift *)
H[a_, w0_] := H0 F[a, w0]; (* Hubble Parameter by Scalefactor *)
ε[z_, w0_] := H0 φ[z, w0]; (* Hubble Parameter by Redshift *)

int[f_, {x_, xmin_, xmax_}] := Quiet[NIntegrate[f, {x, xmin, xmax}, Method -> set, MaxRecursion -> n]];

ta[A_, w0_] := int[1/a/ H[a, w0], {a, 0, A}]; (* Time by Scalefactor *)
α[τ_, w0_]  := Quiet[A /.FindRoot[ta[A, w0] - τ, {A, 1}]] (* Scalefactor by Time *)

tz[Z_, w0_] := int[1/(1 + z)/ ε[z, w0], {z, Z, \[Infinity]}]; (* Time by Redshift *)
χ[τ_, w0_]  := Z /. Quiet[FindRoot[tz[Z, w0] - τ, {Z, 0}]] (* Redshift by Time *)

rH[τ_, w0_] := c/H[α[τ, w0], w0]; (* Hubble Radius *)

lC[τ_, w0_]     := int[-c α[τ, w0]/a^2/H[a, w0], {a, 1, α[τ, w0]}]; (* Light Cone of t0 *)
Lc[τ_, t_, w0_] := int[-c α[τ, w0]/a^2/H[a, w0], {a, α[t, w0], α[τ, w0]}]; (* Light Cone of t *)
eH[τ_, w0_]     := α[τ, w0] int[c/(α[time, w0]), {time, τ, tE}]; (* Event Horizon *)
pH[τ_, w0_]     := int[-α[τ, w0] c/a^2/H[a, w0], {a, α[τ, w0], 0}]; (* Particle Horizon *)
g[τ_, w0_]      := tc /. Quiet[FindRoot[pH[tc, w0]/c - τ, {tc, τ}]]; (* Conformal Time *)

ωR[τ_, w0_] := ΩR α[τ, w0]^-4/ρc[H[α[τ, w0]]]; (* Radiation Evolution *)
ωM[τ_, w0_] := ΩM α[τ, w0]^-3/ρc[H[α[τ, w0]]]; (* Matter Evolution *)
ωK[τ_, w0_] := ΩK α[τ, w0]^-2/ρc[H[α[τ, w0]]]; (* Curvature Evolution *)
ωΛ[τ_, w0_] := ΩΛ α[τ, w0]^(-3 (w[α[τ, w0], w0] + 1))/ρc[H[α[τ, w]]]; (* Dark Energy Evolution *)

t0[w0_] := ta[1, w0]/Gyr; (* Age of the Universe, now *)
"t0 in Gyr" -> t0[-1]

z1  = 8.55; (* Redshift *)
t1  = tz[z1, -1]; "Age at Emission" -> t1/Gyr "Gyr"
tr  = tz[0, -1] - tz[z1, -1]; "Light Travel Time" -> tr/Gyr "Gyr"
lC1 = lC[t1, -1]; "Distance at Emission" -> lC1/Glyr "Glyr"
lC2 = lC[t1, -1] (z1 + 1); "Distance at Absorption" -> lC2/Glyr "Glyr"
v1  = ε[z1, -1] lC1; "Recessional Velocity at Emission" -> v1/c "c"
v2  = H0 lC2; "Recessional Velocity at Absorption" -> v2/c "c"

"y = Light Travel Time, x = Redshift:"
Plot[(tz[0, -1] - tz[z2, -1])/Gyr, {z2, 0, 8.55}, Frame -> True,
 PlotRange -> All, PlotStyle -> {Red, Thick}, GridLines->Automatic]

"y = Distance at Emission, x = Redshift:"
Plot[lC[tz[z2, -1], -1]/Glyr, {z2, 0, 8.55}, Frame -> True,
 PlotRange -> All, PlotStyle -> {Green, Thick}, GridLines->Automatic]

"y = Distance at Absorption, x = Redshift:"
Plot[lC[tz[z2, -1], -1] (z2 + 1)/Glyr, {z2, 0, 8.55}, Frame -> True,
 PlotRange -> All, PlotStyle -> {Blue, Thick}, GridLines->Automatic]

"y = Recessional Velocity at Emission, x = Redshift:"
Plot[ε[z2, -1] lC[tz[z2, -1], -1]/c, {z2, 0, 8.55}, Frame -> True,
 PlotRange -> All, PlotStyle -> {Orange, Thick}, GridLines->Automatic]

"y = Recessional Velocity at Absorption, x = Redshift:"
Plot[H0 lC[tz[z2, -1], -1] (z2 + 1)/c, {z2, 0, 8.55}, Frame -> True,
 PlotRange -> All, PlotStyle -> {Brown, Thick}, GridLines->Automatic]

Bild
Bild
by Simon Tyran, Vienna @ minds || gab || wikipedia || stackexchange || License: CC-BY 4. If images don't load: [ctrl]+[F5]Bild


Zurück zu „Yukterez Notizblock“

Wer ist online?

Mitglieder in diesem Forum: 0 Mitglieder und 3 Gäste