Die geodätische Gleichung

Deutschsprachige Version
Benutzeravatar
Yukterez
Administrator
Beiträge: 196
Registriert: Mi 21. Okt 2015, 02:16

Die geodätische Gleichung

Beitragvon Yukterez » Mi 2. Aug 2017, 20:27

Bild

Verwandte Beiträge: Kerr Newman || Kerr || Reissner Nordström || Schwarzschild || Gravitationslinsen || Raytracing || Flamms Paraboloid
Bild

Code: Alles auswählen

(* |||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||| *)
(* | Mathematica Syntax | GEODESIC SOLVER | geodesics.yukterez.net | Version 20.01.2019 | *)
(* |||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||| *)

ClearAll["Global`*"]

                                               (* Input: kovariante metrische Komponenten *)
gtt=1-(2r-℧^2)/Σ;
grr=-Σ/Δ;
gθθ=-Σ;
gφφ=-Χ/Σ Sin[θ]^2;
gtφ=a (2r-℧^2) Sin[θ]^2/Σ;

                                                                           (* Abkürzungen *)
Σ=r^2+a^2 Cos[θ]^2;
Δ=r^2-2 r+a^2+℧^2;
Χ=(r^2+a^2)^2-a^2 Sin[θ]^2 Δ;
щ=(q ℧ r (a^2+r^2))/(Δ Σ);

              (* Koordinaten, Dimensionen, magnetisches Monopol, elektrische Ladung, Spin *)
x={t, r, θ, φ}; n=4; P=0; Ω=℧; ℧=℧; a=a;

                                                                         "Metrischer Tensor"
metrik={{gtt, 0, 0, gtφ}, {0, grr, 0, 0}, {0, 0, gθθ, 0}, {gtφ, 0, 0, gφφ}};
Subscript["g", μσ] -> MatrixForm[metrik]
inversemetrik=Simplify[Inverse[metrik]];
"g"^μσ -> MatrixForm[inversemetrik]

                                                                            "Maxwell Tensor"
A={(Ω r)/Σ+P/Σ Cos[θ] a, 0, 0, -(Ω r/Σ) Sin[θ]^2 a-P/Σ Cos[θ](r^2+a^2)};
F=Simplify[Table[((D[A[[j]], x[[k]]]-D[A[[k]], x[[j]]])), {j, 1, n}, {k, 1, n}], Reals];
Subscript["F", μσ] -> MatrixForm[F]
f=Simplify[Table[Sum[
inversemetrik[[i, k]] inversemetrik[[j, l]] F[[k, l]],
{k, 1, n}, {l, 1, n}], {i, 1, n}, {j, 1, n}], Reals];
"F"^μσ -> MatrixForm[f]

                                                                        "Christoffelsymbole"
christoffel=Simplify[Table[(1/2)Sum[(inversemetrik[[i, s]])
(D[metrik[[s, j]], x[[k]]]+D[metrik[[s, k]], x[[j]]] -D[metrik[[j, k]], x[[s]]]), {s, 1, n}],
{i, 1, n}, {j, 1, n}, {k, 1, n}]];
Christoffel=Table[If[UnsameQ[christoffel[[i, j, k]], 0],
{ToString[Γ[i, j, k]], christoffel[[i, j, k]]}], {i, 1, n}, {j, 1, n}, {k, 1, j}];
TableForm[Partition[DeleteCases[Flatten[Christoffel], Null], 2]]
                                               
                                                                            "Riemann Tensor"
riemann=Simplify[Table[
D[christoffel[[i, j, l]], x[[k]]] - D[christoffel[[i, j, k]], x[[l]]] +
Sum[christoffel[[s, j, l]] christoffel[[i, k, s]] -
christoffel[[s, j, k]] christoffel[[i, l, s]],
{s, 1, n}], {i, 1, n}, {j, 1, n}, {k, 1, n}, {l, 1, n}]];
Riemann=Table[If[UnsameQ[riemann[[i, j, k, l]], 0],
{ToString[R[i, j, k, l]], riemann[[i, j, k, l]]}],
{i, 1, n}, {j, 1, n}, {k, 1, n}, {l, 1, k - 1}];
TableForm[Partition[DeleteCases[Flatten[Riemann], Null], 2]]
 
                                                                              "Ricci Tensor"
ricci=Simplify[Table[
Sum[riemann[[i, j, i, l]], {i, 1, n}], {j, 1, n}, {l, 1, n}]];
Subscript["Ř", μσ] -> MatrixForm[ricci]
Ricci=Simplify[Table[Sum[
inversemetrik[[i, k]] inversemetrik[[j, l]] ricci[[k, l]], {k, 1, n}, {l, 1, n}],
{i, 1, n}, {j, 1, n}], Reals];
"Ř"^μσ -> MatrixForm[Ricci]
                                                                              "Ricci Skalar"
Ř=Simplify[Sum[inversemetrik[[i, j]] ricci[[i, j]], {i, 1, n}, {j, 1, n}]]; "Ř"->Ř

"Einstein Tensor"
einstein=Simplify[Ricci-Ř metrik/2];
Subscript["G", μσ] -> MatrixForm[einstein]
Einstein=Simplify[Table[Sum[
metrik[[i, k]] metrik[[j, l]] einstein[[k, l]], {k, 1, n}, {l, 1, n}],
{i, 1, n}, {j, 1, n}], Reals];
"G"^μσ -> MatrixForm[Simplify[Einstein]]

rplc[y_]:=(((((((y/.t->t[τ])/.r->r[τ])/.θ->θ[τ])/.φ->φ[τ])/.Derivative[1][t[τ]]->
t'[τ])/.Derivative[1][r[τ]]->r'[τ])/.Derivative[1][θ[τ]]->θ'[τ])/.Derivative[1][φ[τ]]->φ'[τ];
rple[y_]:=(((((((y/.t->t[τ])/.r->r[τ])/.θ->θ[τ])/.φ->φ[τ])/.Derivative[1][t[τ]]->
t'[τ])/. r\.b4->r'[τ])/. θ\.b4->θ'[τ])/. φ\.b4->φ'[τ];
list[y_]:=y[[1]]==y[[2]];

                                                                      "Bewegungsgleichungen"
geodäsie=Simplify[Table[-Sum[
christoffel[[i, j, k]] x[[j]]' x[[k]]'+q f[[i, k]] x[[j]]' metrik[[j, k]],
{j, 1, n}, {k, 1, n}], {i, 1, n}]];

bewegungsgleichung=Table[{x[[i]]''[τ]==Simplify[rplc[geodäsie[[i]]], Reals]}, {i, 1, n}];

geodesic1=bewegungsgleichung[[1]][[1]]
geodesic2=bewegungsgleichung[[2]][[1]]
geodesic3=bewegungsgleichung[[3]][[1]]
geodesic4=bewegungsgleichung[[4]][[1]]

                                                                            "Zeitdilatation"
ṫ=rple[Simplify[Normal[Solve[
-μ==gtt ť^2+grr r\.b4^2+gθθ θ\.b4^2+gφφ φ\.b4^2 + 2 gtφ ť φ\.b4, ť, Reals]]][[2, 1, 2]]-щ];
Derivative[1][t][τ]==ṫ

Für die Anwendung der Einstein Maxwell Gleichungen im Rahmen der Kerr Newman Metrik geht es hier entlang, statische Metriken siehe unten
Bild
Simon Tyran aka Симон Тыран @ minds || vk || wikipedia || stackexchange || wolfram

Benutzeravatar
Yukterez
Administrator
Beiträge: 196
Registriert: Mi 21. Okt 2015, 02:16

Die geodätische Gleichung

Beitragvon Yukterez » So 3. Sep 2017, 07:03

Einfachere Beispiele mit stationär-statischen Metriken (top-down Prinzip). Für die Einstein-Maxwell-Gleichungen geht es hier entlang.
Bild

Benötigte Formeln und Variablen:
Bild

Bild       Bild
Bild

v=√(ṫ²-gtt)/ṫ ist die lokale 3er-Geschwindigkeit, mit v²=vr²+vθ²+vφ². Für Photonen gilt μ=0, für Testpartikel μ=-1. Da es in stationär-statischen Metriken keine Kreuzterme gibt reduziert sich i=vi/√(1-v²)/√(|gii|)-ṫ g0i/gii in den folgenden Beispielen auf i=vi/√(1-v²)/√(|gii|).
Bild

Schwarzschild Limit:
Bild

Bild
Bild

Bild
Bild
Bild
Bild
Bild

Bild
Bild
Bild
Bild
Bild

Bild
Bild
Bild
Bild
Bild

Neutonisches Limit (weak Field):
Bild

Bild
Bild

Bild
Bild
Bild
Bild
Bild

Bild
Bild
Bild
Bild
Bild

Bild
Bild
Bild
Bild
Bild

Minkowski Limit (flache Raumzeit):
Bild

Bild
Bild

Bild
Bild
Bild
Bild
Bild

Bild
Bild
Bild
Bild
Bild

Bild
Bild
Bild
Bild
Bild

Referenzen und weiterführende Literatur, Ref 1) Sean Carroll, Lecture Notes on General Relativity; Schwarzschild: (Kap. 7, #7.29), Weak Field: (Kap. 7, #7.27) Newton: Ref 2) Domingos Soares, From Schwarzschild to Newton (Kap. 3, #13), Ref 3) Kip Thorne, Relativistic Stars and Black Holes (Kap. 25, S. 32 ff. und Kap. 26, #26.9), Minkowski: Ref 4) Heinicke & Hehl, Schwarzschild and Kerr Solutions of Einstein’s Field Equation (Kap. 1.2, #17)Bild
Animations by Simon Tyran, Vienna (Yukterez) - reuse permitted under the Creative Commons License CC BY-SA 4.0
Bild
Simon Tyran aka Симон Тыран @ minds || vk || wikipedia || stackexchange || wolfram


Zurück zu „Yukterez Notizblock“

Wer ist online?

Mitglieder in diesem Forum: 0 Mitglieder und 3 Gäste