Feldgleichungen & Geodäten

Deutschsprachige Version
Benutzeravatar
Yukterez
Administrator
Beiträge: 254
Registriert: Mi 21. Okt 2015, 02:16

Feldgleichungen & Geodäten

Beitragvon Yukterez » Mi 2. Aug 2017, 20:27

Bild

Bild Das ist die deutschsprachige Version.   Bild The english version is available on en.yukterez.net
Bild

Verwandte Beiträge: Kerr Newman || Kerr || Schwarzschild || De Sitter || Gravitationslinsen || Raytracing || Flammsches Paraboloid
Bild


● Feldgleichungs- und Geodätensolver:
Bild

Code: Alles auswählen

(* |||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||| *)
(* | Mathematica Syntax | GEODESIC SOLVER | geodesics.yukterez.net | Version 21.01.2020 | *)
(* |||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||| *)

ClearAll["Local`*"]; smp[y_]:=Simplify[y, Reals]; list[y_]:=y[[1]]==y[[2]];
rplc[y_]:=(((((((y/.t->t[τ])/.r->r[τ])/.θ->θ[τ])/.φ->φ[τ])/.Derivative[1][t[τ]]->
t'[τ])/.Derivative[1][r[τ]]->r'[τ])/.Derivative[1][θ[τ]]->θ'[τ])/.Derivative[1][φ[τ]]->φ'[τ]

                                                      (* kovariante metrische Komponenten *)
g11=gtt=-((-Δ+ж a^2 Sin[θ]^2)/(Σ χ^2));
g22=grr=-Σ/Δ;
g33=gθθ=-Σ/ж;
g44=gφφ=-((ж σ^2 Sin[θ]^2-a^2 Δ Sin[θ]^4)/(Σ χ^2));
g14=gtφ=-(( a (Δ-ж σ) Sin[θ]^2)/(Σ χ^2));
g12=g13=g23=g24=g34=0;

                                                                           (* Abkürzungen *)
Σ=r^2+a^2 Cos[θ]^2;
Δ=(r^2+a^2)(1-Λ/3 r^2)-2 M r+℧^2;
Χ=(r^2+a^2)^2-a^2 Sin[θ]^2 Δ;
щ=(q ℧ r (a^2+r^2))/(Δ Σ);
χ=1+Λ/3 a^2;
ж=1+Λ/3 a^2 Cos[θ]^2;
σ=a^2+r^2;

                           (* Dimensionen, elektrische Ladung, Spin, Vakuumenergie, Masse *)
x={t, r, θ, φ}; n=4; Ω=℧; ℧=℧; a=a; Λ=Λ; M=1;

                                                                         "Metrischer Tensor"
mt=smp[{
{g11, g12, g13, g14},
{g12, g22, g23, g24},
{g13, g23, g33, g34},
{g14, g24, g34, g44}
}];
Subscript["g", μσ] -> MatrixForm[mt]
it=smp[Inverse[mt]];
"g"^μσ -> MatrixForm[it]

                                                                            "Maxwell Tensor"
A={Ω r/Σ/χ, 0, 0, -Ω r/Σ/χ Sin[θ]^2 a};
F=ParallelTable[smp[((D[A[[j]], x[[k]]]-D[A[[k]], x[[j]]]))], {j, 1, n}, {k, 1, n}];
Subscript["F", μσ] -> MatrixForm[F]
f=smp[ParallelTable[Sum[
it[[i, k]] it[[j, l]] F[[k, l]],
{k, 1, n}, {l, 1, n}], {i, 1, n}, {j, 1, n}]];
"F"^μσ -> MatrixForm[f]

                                                                        "Christoffelsymbole"
chr=ParallelTable[smp[(1/2)Sum[(it[[i, s]])
(D[mt[[s, j]], x[[k]]]+D[mt[[s, k]], x[[j]]] -D[mt[[j, k]], x[[s]]]), {s, 1, n}]],
{i, 1, n}, {j, 1, n}, {k, 1, n}];
crs=ParallelTable[If[UnsameQ[chr[[i, j, k]], 0],
{ToString[Γ[i, j, k]] "\[Rule]", chr[[i, j, k]]}], {i, 1, n}, {j, 1, n}, {k, 1, j}];
TableForm[Partition[DeleteCases[Flatten[crs], Null], 2]]
                 
                                                                 "gemischter Riemann Tensor"
rmn=ParallelTable[smp[
D[chr[[i, j, l]], x[[k]]] - D[chr[[i, j, k]], x[[l]]] +
Sum[chr[[s, j, l]] chr[[i, k, s]] -
chr[[s, j, k]] chr[[i, l, s]],
{s, 1, n}]], {i, 1, n}, {j, 1, n}, {k, 1, n}, {l, 1, n}];
rie=ParallelTable[If[UnsameQ[rmn[[i, j, k, l]], 0],
{ToString[R[i, j, k, l]] "\[Rule]", rmn[[i, j, k, l]]}],
{i, 1, n}, {j, 1, n}, {k, 1, n}, {l, 1, k - 1}];
TableForm[Partition[DeleteCases[Flatten[rie], Null], 2]]
                                                            (* kovarianter Riemann Tensor *)
rcv=ParallelTable[Sum[mt[[i, j]] rmn[[j, k, l, m]], {j, 1, 4}],
{i, 1, n}, {k, 1, n}, {l, 1, n}, {m, 1, n}];
                                                        (* kontravarianter Riemann Tensor *)
rcn=ParallelTable[Sum[it[[m, i]] it[[h, j]] it[[o, k]] it[[p, l]] rcv[[i, j, k, l]],
{i, 1, 4}, {j, 1, n}, {k, 1, n}, {l, 1, n}],
{m, 1, 4}, {h, 1, n}, {o, 1, n}, {p, 1, n}];

                                                                              "Ricci Tensor"
rcc=ParallelTable[smp[
Sum[rmn[[i, j, i, l]], {i, 1, n}]], {j, 1, n}, {l, 1, n}];
Subscript["Ř", μσ] -> MatrixForm[rcc]
ric=ParallelTable[smp[Sum[
it[[i, k]] it[[j, l]] rcc[[k, l]], {k, 1, n}, {l, 1, n}]],
{i, 1, n}, {j, 1, n}];
"Ř"^μσ -> MatrixForm[ric]

                                                                              "Ricci Skalar"
Ř=smp[Sum[it[[i, j]] rcc[[i, j]], {i, 1, n}, {j, 1, n}]]; "Ř"->Ř

                                                                        "Kretschmann Skalar"
krn= smp[Sum[rcv[[i, j, k, l]] rcn[[i, j, k, l]],
{i, 1, 4}, {j, 1, n}, {k, 1, n}, {l, 1, n}]];
"K"->krn

                                                                           "Einstein Tensor"
est=smp[ric-Ř mt/2];
Subscript["G", μσ] -> MatrixForm[est]
ein=ParallelTable[smp[Sum[
mt[[i, k]] mt[[j, l]] est[[k, l]], {k, 1, n}, {l, 1, n}]],
{i, 1, n}, {j, 1, n}];
"G"^μσ -> MatrixForm[ein]

                                                                     "Stress Energie Tensor"
set=smp[est+Λ mt]/8/π;                                                   
Subscript["T", μσ] -> MatrixForm[set]
sei=ParallelTable[smp[Sum[
mt[[i, k]] mt[[j, l]] set[[k, l]], {k, 1, n}, {l, 1, n}]],
{i, 1, n}, {j, 1, n}];
"T"^μσ -> MatrixForm[sei]

                                                                      "Bewegungsgleichungen"
geo=ParallelTable[smp[-Sum[
chr[[i, j, k]] x[[j]]' x[[k]]'+q f[[i, k]] x[[j]]' mt[[j, k]],
{j, 1, n}, {k, 1, n}]], {i, 1, n}];

equ=ParallelTable[{x[[i]]''[τ]==smp[rplc[geo[[i]]]]}, {i, 1, n}];

geodesic1=equ[[1]][[1]]
geodesic2=equ[[2]][[1]]
geodesic3=equ[[3]][[1]]
geodesic4=equ[[4]][[1]]

                                                                     "totale Zeitdilatation"
H=Sum[mt[[μ, ν]] x[[μ]]' x[[ν]]', {μ, 1, n}, {ν, 1, n}];                       
ṫ=Quiet[rplc[smp[Normal[Solve[
-μ==(H/.t'->ť), ť]]]]];
Derivative[1][s][τ]^2 == "ds²/dτ² == -μ" == smp[rplc[H]]                     
Derivative[1][t][τ]->ṫ[[1, 1, 2]]||ṫ[[2, 1, 2]]||rplc[Sqrt[it[[1, 1]]]]/Sqrt[1-μ^2 v[τ]^2]

                                                                  "kovarianter Viererimpuls"
p[μ_]:=-(Sum[mt[[μ, ν]]*x[[ν]]', {ν, 1, n}]+q A[[μ]]);
pt[τ]->rplc[smp[p[1]]]
pr[τ]->rplc[smp[p[2]]]
pθ[τ]->rplc[smp[p[3]]]
pφ[τ]->rplc[smp[p[4]]]

                                                                    "lokale Geschwindigkeit"
V[x_]:=smp[Normal[Solve[vx Sqrt[-mt[[x, x]]]/Sqrt[1-μ^2 v[τ]^2]-(1-μ^2 v[τ]^2) q A[[x]]==
p[x], vx]][[1, 1]]];                                                   
rplc[V[2]]/.vx->vr[τ]
rplc[V[3]]/.vx->vθ[τ]
rplc[V[4]]/.vx->vφ[τ]









BildDer Solver ist mit der KNdS-Metrik in {t,r,θ,φ}-BL-Koordinaten voreingestellt. Mit Λ=0 reduziert sich die Metrik auf Kerr Newman, mit Λ=℧=0 auf Kerr, mit Λ=a=0 auf Reissner Nordström, mit Λ=℧=a=0 auf Schwarzschild, mit ℧=a=0 auf Schwarzschild De Sitter, mit ℧=a=M=0 auf De Sitter und mit Λ=℧=a=M=0 auf Minkowski. Bei der Eingabe einer kartesischen Metrik werden die Koordinaten entsprechend umbenannt (x={t,r,θ,φ}→x={t,X,Y,Z} usw). Falls das Linienelement in einer unübersichtlichen Form vorliegt können die metrischen Koeffizienten mit dem Linienelementzerleger sauber getrennt und hernach in den Geodätensolver eingegeben werden.
Bild

● Beispiele verschiedener Metriken in unterschiedlichen Koordinaten:
Bild
BildBoyer Lindquist ist das rotierende Äquivalent zu Droste (Zeit des stationären Beobachters), Kerr-Schild zu Finkelstein (Koordinatenzeit wird per einfallenden Lichtstrahlen aufgestempelt) und Doran zu Raindrop Koordinaten (t wird durch mit der negativen Fluchtgeschwindigkeit freifallende Uhren definiert). In den Bewegungsgleichungen sind die Koordinaten Funktionen der Eigenzeit bzw. bei Photonen des affinen Parameters (t→t[τ], r'→r'[τ], θ''→θ''[τ] usw), in manchen Beispielen mit kilometerlangem Output wird dies der Kürze wegen und da es sich sowieso aus dem Zusammenhang ergibt nicht extra angeschrieben (die rplc Funktion ist dann deaktiviert, im Code ist sie jedoch standardmäßig aktiviert damit der Output bei Bedarf gleich direkt in den Simulator übertragen werden kann). Sofern nicht anders angegeben werden natürliche Einheiten mit G=M=c=K=1 verwendet (Längen haben die Einheit GM/c², Zeiten GM/c³, Geschwindigkeiten c, etc). Der einheitsbehaftete Wert der kosmologischen Konstante ist in unserem Universum Λ=1.1056e-52/m² (im Kontext eines schwarzen Lochs mit M=1e40kg wäre das dimensionslos Λ→G²M²Λ/c⁴=6.0963e-87), wobei die Vakuumdichte ρΛ=c²Λ/(8πG) beträgt.
Bild

● Koordinatentransformator:
Bild

Code: Alles auswählen

(* |||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||| *)
(* | KOORDINATEN TRANSFORMATOR | geodesics.yukterez.net | Version 14.1.2020 ||||||||||||| *)
(* |||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||| *)

d1={dt,dr,dθ,dφ};
d2={dT,dr,dθ,dφ};
n=4;

v=-Sqrt[2M/r];
dt=dT+v/(1-v^2)dr ;

g11=gtt=1-2M/r;
g22=grr=-1/gtt;
g33=gθθ=-r^2;
g44=gφφ=-r^2 Sin[θ]^2;
g12=g13=g14=g23=g24=g34=0;

m1={
{g11,g12,g13,g14},
{g12,g22,g23,g24},
{g13,g23,g33,g34},
{g14,g24,g34,g44}};
M1=MatrixForm[m1];

m2=FullSimplify[Table[Sum[D[d1[[k]],d2[[i]]] D[d1[[s]],d2[[j]]] m1[[k,s]],
{k,1,n},{s,1,n}],{i,1,n},{j,1,n}]];
M2=MatrixForm[m2];

M1->M2








BildTransformation von einem Koordinatensystem in ein anderes. Input: vorhandene kovariante Metrik und Transformationsregel für die Koordinaten, Output: neue kovariante Metrik (für die praktische Anwendung siehe das Beispiel unten).
Bild

● Beispiel zur Koordinatentransformation:
Bild
Bild
Bildoben: Transformationsregel, unten: Transformation
Bild
BildBeispiel zum Koordinatentransformator: Eingabe der Schwarzschild Metrik in kovarianten Droste Bookkeeper Koordinaten (links) und der Transformationsregel dT=dt-v γ² dr, Ausgabe: Schwarzschild Metrik in kovarianten Gullstrand Painlevé (Raindrop) Koordinaten (rechts). Für die Rücktransformation klick aufs Bild. Äquivalente Transformation für die Kerr Newman Metrik (Boyer Lindquist zu Doran): klick.
Bild

● Funktionsplotter:
Bild

Code: Alles auswählen

(* |||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||| *)
(* | Mathematica Syntax | EINSTEIN PLOTTER | geodesics.yukterez.net | Version 10.1.2020 | *)
(* |||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||| *)

(* Kartesisch zu Boyer Lindquist *)
k[x_, z_, a_]:=FindInstance[x==Sqrt[R^2+a^2]Sin[u]&&z==R Cos[u]&&u<2Pi&&u>=0&&R>=0, {R, u}, Reals]
r[x_, z_, a_]:=k[x, z, a][[1, 1, 2]];
θ[x_, z_, a_]:=k[x, z, a][[1, 2, 2]];

(* Kretschmann Skalar *)
K[x_, z_, a_, ℧_]:=-(1/((a^2+a^2 Cos[2 θ[x, z, a]]+2 r[x, z, a]^2)^6))32 (30 a^6-42 a^4 ℧^4+3 a^6 Cos[6 θ[x, z, a]]+360 a^4 ℧^2 r[x, z, a]-540 a^4 r[x, z, a]^2+272 a^2 ℧^4 r[x, z, a]^2-960 a^2 ℧^2 r[x, z, a]^3+720 a^2 r[x, z, a]^4-112 ℧^4 r[x, z, a]^4+192 ℧^2 r[x, z, a]^5-96 r[x, z, a]^6+2 a^4 Cos[4 θ[x, z, a]] (9 a^2-7 ℧^4+60 ℧^2 r[x, z, a]-90 r[x, z, a]^2)+a^2 Cos[2 θ[x, z, a]] (45 a^4+16 r[x, z, a]^2 (17 ℧^4-60 ℧^2 r[x, z, a]+45 r[x, z, a]^2)-8 a^2 (7 ℧^4-60 ℧^2 r[x, z, a]+90 r[x, z, a]^2)));

(* Horizonte und Ergosphären *)
rE=1+Sqrt[1-a^2 Cos[Θ]^2-a^2];(*äußere Ergosphäre*)
RE={Sqrt[rE^2+a^2] Sin[Θ], rE Cos[Θ]};
rG=1-Sqrt[1-a^2 Cos[Θ]^2-a^2];(*innere Ergosphäre*)
RG={Sqrt[rG^2+a^2] Sin[Θ], rG Cos[Θ]};
rA=1+Sqrt[1-a^2-a^2];(*äußerer Horizont*)
RA={Sqrt[rA^2+a^2] Sin[Θ], rA Cos[Θ]};
rI=1-Sqrt[1-a^2-a^2];(*innerer Horizont*)
RI={Sqrt[rI^2+a^2] Sin[Θ], rI Cos[Θ]};

(* Kartesischer Plot *)
℧=a;
Do[Print[Rasterize[Grid[{{
Show[
ContourPlot[K[x, z, a, ℧], {x, 0, 5}, {z, 0, 5}, PlotLegends->Automatic, Contours->20, ContourShading->Automatic, MaxRecursion->3, ImageSize->400],
ParametricPlot[{RI, RA, RG, RE}, {Θ, 0, Pi/2}, Frame->False]
]}, {"a"->[email protected]}, {"℧"->[email protected]℧},
{"                                                                                  "}},
Alignment->Left]]],
{a, 0, Sqrt[1/2], Sqrt[1/2]/2}]








BildDer Plotter ist auf einen Konturplot des Kretschmann Skalars für die Kerr Newman Metrik eingestellt. Andere Funktionen können aus dem Solver kopiert und eingesetzt werden, wobei bei der Projektion auf die x,z-Ebene die r,θ-Koordinaten als Funktionen von x,z angeschrieben gehören (r→r[x,z,a], θ→θ[x,z,a]).
Bild

● Beispiel zur Visualisierung:
Bild
Bild
BildIn diesem Beispiel wird der Kretschmann Skalar für ein Kerr Newman SL bei y=0 auf die x,z-Ebene projiziert und mit den Horizonten und Ergosphären überblendet. Die schwarzen Kurven bezeichnen Flächen konstanter Krümmung; die geclippten Bereiche sind weiß markiert und je nachdem entweder stark positiv oder stark negativ gekrümmt. Gebündelte schwarze Kurven die weiße Flächen separieren sind harte Übergänge zwischen positiver und negativer Krümmung. Für andere Spin- und Ladungskombinationen wird auf das obere Bild geklickt, um die Animation einzuschalten klick hier. Für die Bahnen von bewegten Testpartikeln oder Photonen siehe ganz oben unter "verwandte Beiträge".
Bild

● Benötigte Gleichungen und Regeln:
Bild

Feldgleichung in Abhängigkeit vom kovarianten Energie-Impuls-Tensor Tij:

Bild
Bild

Riemann Tensor:

Bild

Ricci Tensor:

Bild

Ricci Skalar:

Bild

Kretschmann Skalar:

Bild

Einstein Tensor:

Bild

Kronecker Delta:

Bild

Christoffelsymbole zweiter Art:

Bild

Hamiltonian, Partikel: μ=-1, Photonen: μ=0:

Bild

Maxwell Tensor mit dem Vektorpotential A:

Bild
Bild

Erste Eigenzeitableitung und Impuls:

Bild

Totale Zeitdilatation und lokale Geschwindigkeit:

Bild

Zweite Eigenzeitableitung, Viererbeschleunigung:

Bild

Paralleltransport eines Vektors V:

Bild
Bild

Indexverschieberegel:

Bild

Mehrere Indizes:

Bild

Kontraktion:

Bild

Gemischte Indizes:

Bild
Bild

Transformation von einem Koordinatensystem x in ein anderes x̅:

Bild

Bild
Bild

In diesem Beitrag werden natürliche Einheiten verwendet. Der Overdot steht für die Ableitung nach der Eigenzeit τ: ẋ=dx/dτ
Bild

● Empfohlene Tutorials:
Bild

images and animations by Simon Tyran, Vienna (Yukterez) - reuse permitted under the Creative Commons License CC BY-SA 4.0
Bild
Simon Tyran aka Симон Тыран @ vk || minds || parler || gab || wikipedia || stackexchange || wolframBild

Zurück zu „Yukterez Notizblock“

Wer ist online?

Mitglieder in diesem Forum: 0 Mitglieder und 4 Gäste